The-Aether-II/build.gradle

buildscript {
    repositories {
        jcenter()
        maven {
            name = "forge"
            url = "http://files.minecraftforge.net/maven"
        }
    }
    dependencies {
        classpath 'net.minecraftforge.gradle:ForgeGradle:2.3-SNAPSHOT'
    }
}

apply plugin: 'net.minecraftforge.gradle.forge'
apply plugin: 'maven-publish'

def isPhosphorSubmodule = findProject(":Phosphor") != null

repositories {
    mavenCentral()

    maven { url = 'https://repo.spongepowered.org/maven' }
    maven { url = 'https://repo.gildedgames.com/maven' }
}

configurations {
    shaded
    shaded.exclude group: "org.spongepowered"
}

dependencies {
    if (isPhosphorSubmodule) {
        runtime project(':phosphor')
    } else {
        runtime "me.jellysquid.mods:phosphor:${phosphor_version}:dev"
        shaded  "me.jellysquid.mods:phosphor:${phosphor_version}:universal"
    }

    compile project(":orbis-lib")
    shaded project(":orbis-lib")
}

allprojects {
    sourceCompatibility = 1.8
    targetCompatibility = 1.8
}

if (System.getenv("BUILD_NUMBER") != null) {
    version = "${minecraft_version}-${mod_version}+build${System.getenv("BUILD_NUMBER")}"
} else {
    version = "${minecraft_version}-${mod_version}-SNAPSHOT"
}

group = "com.gildedgames"
archivesBaseName = "aether_ii"

sourceSets {
    api {
        java { srcDir "src/api/java" }
    }
    test {
        java { srcDir "src/test/java" }
    }
}

jar {
    from sourceSets.api.output
    from sourceSets.main.output

    classifier "universal"

    gradle.projectsEvaluated({
        def artifacts = configurations.shaded.files
                .findAll { it.name.contains("-universal.jar") }
                .toList()
                .reverse()

        from(artifacts)

        manifest {
            attributes "ContainedDeps": artifacts.collect { it.name }.join(' ')
            attributes "FMLAT": "aether_at.cfg"
            attributes "SignedFileName": jar.archivePath.name
        }
    })
}

task apiJar(type: Jar) {
    classifier = "api"

    from sourceSets.api.output
}

minecraft {
    version = "$minecraft_version-$forge_version"
    mappings = "$forge_mappings"

    runDir = "run"

    def plugin = "me.jellysquid.mods.phosphor.core.PhosphorFMLLoadingPlugin"

    clientJvmArgs = serverJvmArgs += "-Dfml.coreMods.load=$plugin"
}

processResources {
    inputs.property "version", project.version
    inputs.property "mcversion", project.minecraft.version

    from(sourceSets.main.resources.srcDirs) {
        include 'mcmod.info'

        expand 'version': project.version, 'mcversion': project.minecraft.version
    }

    from(sourceSets.main.resources.srcDirs) {
        exclude 'mcmod.info'
    }
}

idea {
    module {
        inheritOutputDirs = true
    }
}

// We disable this because Gradle will fail to build otherwise for some reason.
// See https://github.com/MinecraftForge/Srg2Source/issues/10
minecraft {
    makeObfSourceJar = false
}

if (System.getenv("JARSIGN_SECRETS_FILE") != null) {
    def secretsFile = file(System.getenv("JARSIGN_SECRETS_FILE"))

    def secrets = new Properties()
    secrets.load(secretsFile.newReader())

    [jar, apiJar].each { jarTask ->
        def task = task(jarTask.name + 'Sign', type: SignJar) {
            keyStore = System.getenv("JARSIGN_KEYSTORE_FILE")
            alias = secrets.alias
            storePass = secrets.storePassword
            keyPass = secrets.keyPassword

            inputFile = jarTask.archivePath
            outputFile = jarTask.archivePath
        }

        build.dependsOn task
    }
}

build.dependsOn apiJar

jar.dependsOn ":orbis-lib:build"